xsetech - sélectionne la sous-fenêtre d'une fenêtre graphique pour les dessins
xsetech est principalement utilisée pour définir la sous-fenêtre d'une fenêtre graphique, à utiliser pour les dessins. La sous-fenêtre est définie par wrect=[x,y,w,h] (point en haut à gauche, largeur, hauteur). Les valeurs dans wrect sont spécifiées sous forme de proportions de la largeur et de la hauteur de la fenêtre graphique courante. Par exemple wrect=[0,0,1,1] signifie que toute la fenêtre graphique sera utilisée, et wrect=[0.5,0,0.5,1] signifie que l'on sélectionne la moitié droite de la fenêtre graphique.
xsetech permet aussi de définir l'échelle graphique pour les dessins 2D et peut être utilisée préalablement à des commandes nécessitant que l'échelle soit déjà définie (par exemple strf="x0z" ou frameflag=0 dans plot2d ).
frect=[xmin,ymin,xmax,ymax] est utilisé pour changer l'échelle graphique et est similaire à l'argument rect de plot2d . Si frect n'est pas donné la valeur courante de l'échelle graphique n'est pas modifiée. La valeur par défaut de rect est [0,0,1,1] (à la création de la fenêtre, ou par exemple après un xset('default') ou après effacement complet de la fenêtre avec xbasc() ).
arect=[x_gauche, x_droite, y_haut, y_bas] est utilisé pour définir le cadre dans la sous-fenêtre. Le cadre est spécifié (comme wrect ) en utilisant des proportions de la largeur et de la hauteur de la sous-fenêtre courante. La valeur par défaut est 1/8*[1,1,1,1] . Si arect n'est pas donné le cadre courant n'est pas modifié.
// pour avoir une explication des paramètres de xsetech() taper :
exec('SCI/demos/graphics/xsetechfig.sce');
// On coupe la fenêtre en deux
// D'abord on choisit la première sous-fenêtre
// et l'échelle
xsetech([0,0,1.0,0.5],[-5,-3,5,3])
// on appelle plot2d avec l'option "001" pour utiliser l'échelle
// choisie par xsetech
plot2d([1:10]',[1:10]',1,"001"," ")
// on choisit la deuxième sous-fenêtre
xsetech([0,0.5,1.0,0.5])
// l'échelle est [0,0,1,1] par défaut
// on la change avec l'argument rect de plot2d
plot2d([1:10]',[1:10]',1,"011"," ",[-6,-6,6,6])
// 4 dessins sur une seule fenêtre
xbasc()
xset("font",2,0)
xsetech([0,0,0.5,0.5]); plot3d()
xsetech([0.5,0,0.5,0.5]); plot2d()
xsetech([0.5,0.5,0.5,0.5]); grayplot()
xsetech([0,0.5,0.5,0.5]); histplot()
// retour aux valeurs par défaut
xsetech([0,0,1,1])
// Un dessin avec arect change
xbasc()
xset("default")
xsetech(arect=[0,0,0,0])
x=1:0.1:10;plot2d(x',sin(x)')
xbasc()
xsetech(arect=[1/8,1/8,1/16,1/4])
x=1:0.1:10;plot2d(x',sin(x)')
xbasc()
xset("default")
xgetech , subplot , isoview , square ,
J.Ph.C.